Tính toán thời gian và rung động trong kết cấu

Trong bài này chúng ta sẽ khảo sát một bản mặt cầu chịu động đất gây ra tức thời. Và sử dụng phương pháp tức thời trong ANSYS (Transient ANALYSIS) để giải quyết toàn toán này, một phần nữa là bài toán sử dụng phương pháp điều kiện biên động để đưa ra kết quả ứng xuất. Một bản mặt cầu có kích thước 20x20m làm bằng bê tông, chịu động đất trong 10 giây và nó được thiết kế giảm dư chấn 5% (structure damping). Sử dụng  ANSYS để đưa ra biểu đồ dư chấn cho bản mặt cầu này.

Dễ dàng mô hình bải toán được như sau: (Để mô hình bài toán các bạn nên xem lại bài trước)

Kết quả đo đạc chỉ ra rằng bản mặt cầu có chuyển vị đưa ra trong một file dữ liệu: Zdispmod.txt

(Bấm phải chuột chọn SAVE AS để tải file dữ liệu về).

Giải bài toán:

Solution -> New Anlysis -> Transient

Sol'n Control:

                 + Time at end of loadstep: 10.01

                 + Automatic time stepping: On

                 + Frequency: Write every substep

                 + Time step size:  0.01

                 + Mass matrix muitplier: 1.5708

                 + Stiffness matrix multiplier: 0.0008842

                 + GAMA: 0.005

Để đọc được file dữ liệu của trận động đất bạn cần phải sử dụng lệnh VREAD để đọc được dữ liệu bài toán, dưới đây là log file của bài toán:

/prep7
ET,1,SHELL43 ! sử dụng bản shell43 để mô hình bản bê tông
KEYOPT,1,3,0
KEYOPT,1,4,0
KEYOPT,1,5,0
KEYOPT,1,6,0
R,1,1.5,1.5,1.5,1.5, , 
RMORE, ,3600,  
MP,EX,1,2e10  
MP,PRXY,1,0.3
n,1,0,0,0
ngen,21,1,1,,1,1
ngen,21,21,1,21,1,,,1
e,1,2,23,22
egen,20,1,1
egen,20,21,1,20,1

d,1,UY,0,,21,1,UZ,UX            ! chuyên vị ban đầu khi chưa xảy ra động đất
d,421,UY,0,,441,1,UZ,UX     
d,22,UX,0,,400,21,UY,UZ
d,42,UX,0,,420,21,UY,UZ
FINISH

/SOLU
ANTYP,TRANS                      !  Đặt chế độ chạy transient
!
*DIM,D1,TABLE,1000,1          ! khai báo biên để lưu chuyển vị của động đất
*DIM,D2,TABLE,1000,1          ! khai báo biên để lưu chuyển vị của động đất
*DIM,D3,TABLE,1000,1          ! khai báo biên để lưu chuyển vị của động đất   
!
*VREAD,D1(1,1),E:\Zdispmod,txt       ! Đọc chuyên vị theo phương X
(F20.0)
*VFILL,D1(1,0),RAMP,0.0,0.010
D1(0,1)=1.0
*VPLOT,D1(1,0),D1(1,1)
*VREAD,D2(1,1),E:\Zdispmod,txt       ! Đọc chuyên vị theo phương Y
(F20.0)
*VFILL,D2(1,0),RAMP,0.0,0.010
D2(0,1)=1.0
*VPLOT,D2(1,0),D2(1,1)
*VREAD,D3(1,1),E:\Zdispmod,txt       ! Đọc chuyên vị theo phương  Z
(F20.0)
*VFILL,D3(1,0),RAMP,0.0,0.010
D3(0,1)=1.0
*VPLOT,D3(1,0),D3(1,1)
TIME,0.01                                       ! bước chạy theo thời gian
DT=0.01
T0=0.02
T1=10.01                                        ! thời gian kết thúc động đấy
OUTRES,ALL,ALL
ALPHAD,1.5708                                ! ma trận khối lượng tham ra trong khi động đất xảy ra
BETAD,0.0008842
DMPRAT,0.05        ! khả năng chống lại động đất
TIMINT,OFF        ! điều kiện ban đầu của tải trọng bản thân
DELTIM,0.01
KBC,1
ACEL,0.0,0,0.0      ! gia tốc trọng trường theo phương X, Y ,Z. Nếu muốn bạn them 9.81 vào theo phương y
SOLVE
TIMINT,ON         ! điều kiện của kết cấu
KBC,0
DELTIM,0.01
AUTOTS,ON                            ! tự động tăng theo thời gian 0.01
*DO,T,T0,T1,DT
   TIME,T
   ACEL,0.0,0,0.0

!* xác lập chuyển vị liên tục tại các node ngoài cùng của bản mặt cầu
d,1,UY,D1(T),,21,1,UZ,UX          ! kết cấu bắt đầu chịu chuyển vị do động đất, điều kiện biên động được xác lập từ file chuyển vị
d,421,UY,D1(T),,441,1,UZ,UX
d,22,UX,D1(T),,400,21,UY,UZ
d,42,UX,D1(T),,420,21,UY,UZ
   SOLVE             
*ENDDO
!

/POST26
NUMVAR,200                           
NSOL,2,221,U,Y,Testies
filldata,5,1,1000,1,0.1,0.1             ! kết quả sẽ được đưa vào bảng dữ liệu
RESP,6,5,2,3,0.05 ,0.01,0.1,10
XVAR,5 
PLVAR,6

Để chạy bài toán này bạn cần khoảng 5 phút và dung lượng ổ cứng khoảng 500MB

Kết quả thu được khi hoàn thành.

- Để xem ứng xuất chạy theo thời gian động đất:

Sau khi bấm OK bạn sẽ thu được Video về bản mặt cầu bị dung lắc khi động đấy xả ra.